plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.8' apply false
    id 'io.spring.dependency-management' version '1.1.7' apply false
}

allprojects {
    group 'me.lenajenichen'
    version '0.0.1-SNAPSHOT'

    repositories {
        mavenCentral()
    }
}

subprojects {

    apply plugin: 'java'

    // Only the actual service applications (under :services:...) are Spring Boot apps.
    // Aggregator/helper projects like :services and :test should not apply Spring Boot.
    if (project.path.startsWith(':services:')) {
        apply plugin: 'org.springframework.boot'
        apply plugin: 'io.spring.dependency-management'

        dependencies {
            implementation 'org.springframework.boot:spring-boot-starter'
            implementation 'org.springframework.boot:spring-boot-starter-web'
            // Ensure R2DBC SPI is on the classpath to satisfy Boot's autoconfiguration checks
            implementation 'io.r2dbc:r2dbc-spi'

            testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.1'
            testImplementation 'org.springframework.boot:spring-boot-starter-test'
            testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.1'
        }
    }

    tasks.withType(Test).configureEach {
        useJUnitPlatform()
    }
}